# POPULATION PYRAMID
# Script last modified 03-Jun-2010

scale = 1000000 # ADJUST AS NECESSARY
# The increment would better be automatic, but "set xtics" doesn't
# allow to specify start only.
increment = 0.5 # ADJUST THIS AS NECESSARY
gap_width = 0.11 # ADJUST THIS AS NECESSARY

# ADJUST TITLES AS NECESSARY
set title "Population of Saudi Arabia (2009)"
set xlabel "Population (in millions)"

# Input file contains comma-separated values fields
set datafile separator ","

# Plot to dummy device and retrieve the male/female population range
set term unknown

set autoscale xfix
plot "data.csv" using ($4/scale):2, "data.csv" using (-$5/scale):2

range_male = (GPVAL_X_MAX > -GPVAL_X_MIN) ? GPVAL_X_MAX : -GPVAL_X_MIN
range_female = range_male
central_gap = (range_male + range_female) * gap_width

#set term png transparent truecolor size 640,400
set term svg size 800,500 dynamic font "sans-serif"

set style data boxxyerrorbars
set style fill solid 0.5 border

# Y axis is invisible
unset ytics
set autoscale yfix

# X axis is labeled from zero onwards, with the given increment
set xtics nomirror 0,increment

plot [-range_female-central_gap:range_male]\
 "data.csv" using (0):2:(0):($5/scale):($2+1):($2+5)\
  title "Females" linetype rgb "#AA3F74",\
 "data.csv" using (-central_gap/2):($2+2.5):2 title "" with labels font "sans-serif,10"
 
set key left Left reverse
 
plot [range_female:-central_gap-range_male]\
 "data.csv" using (0):2:(0):($4/scale):($2+1):($2+5)\
  title "Males" linetype rgb "#296DCC"